google sonuçlarını parser lemek

26-11-2009, 12:02:12

#1

r10ceylan

Merhabalar;

Sitemde düşündüğüm bir yapılanma var. Etiketleme sistemi kurmak istiyorum. Ancak sitemdeki veriler sabit bir mantık ile kurulmadığından, wp veya joomla daki gibi bir etiketlemeye gidemiyorum.

Yapmak istediğim şudur:

Siteme gelen ziyaretcilerin anahtar kelimelerini analiz edip, buna göre bu kelimeleri tag klasörü altında link vermek istiyorum. Linklerden dönen sonuçları ise, google' da yaptığımız site:www.site.com anahtar kelime şeklinde çıkan sonuçları sitemde yayınlamak istiyorum. Bunun için google sonuçlarını parser yapacak bir yazılıma ihtiyacım var.

İnternetten araştırdım karşıma çıkan google api olayı oldu. Ancak google api' de siteye ajax formatında arama motoru koymanın haricinde yukarda ifade ettiğim özellikleri bulamadım. Yabancı kaynak olduğundan dilim de yetmemiş olabilir bunun için.

Bu konuda elinde kod olan varsa, yardımcı olmasını isterim.

Teşekkür eder, kolaylıklar dilerim...

26-11-2009, 13:36:21

Eposta Aktivasyonu Gerekmekte

şöyle bir kod belki işini görür

<%@LANGUAGE="VBSCRIPT" CODEPAGE="1254"%>
<%
Function fonkVeriCek(strVeri, strBaslamaEtiket, strBitisEtiket)
dim intBaslama
 intBaslama = InStr(1, strVeri, strBaslamaEtiket, vbTextCompare)
if intBaslama then
 intBaslama = intBaslama + Len(strBaslamaEtiket)
 intBitis = InStr(intBaslama + 1, strVeri, strBitisEtiket, vbTextCompare)
 fonkVeriCek = CStr(Mid(strVeri, intBaslama, intBitis - intBaslama))
else
 fonkVeriCek = " " 
end if
End Function

function fonkXmlHttp(strUrl)
dim objXmlHttp
set objXmlHttp = Server.CreateObject("Microsoft.XMLHTTP") 
 objXmlHttp.Open "GET", strUrl, false
 objXmlHttp.SetRequestHeader "Pragma", "no-cache"
 objXmlHttp.SetRequestHeader "Cache-control", "no-cache"
on error Resume next
 objXmlHttp.Send
if Err.Number<>0 then
 fonkXmlHttp = ""
exit function
end If
on error Goto 0
if (objXmlHttp.Status = 200) then
 fonkXmlHttp = objXmlHttp.ResponseText
 fonkXmlHttp = fonkStream(objXmlHttp.ResponseBody,"utf-8") 
else
 fonkXmlHttp = "Hata : " & objXmlHttp.StatusText
end if
end function

function fonkStream(Veri,KarakterSet)
dim objStream
set objStream = Server.CreateObject("ADODB.Stream")
 objStream.Type = 1
 objStream.Mode = 3
 objStream.Open
 objStream.Write Veri
 objStream.Position = 0
 objStream.Type = 2
 objStream.Charset = KarakterSet
 fonkStream = objStream.ReadText 
 objStream.Close
set objStream = Nothing
end function
%>

<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-9" />
<title>GoogleBot Yapımı</title>
<style type="text/css">
<!--
.baslik {
	font-family: Calibri;
	font-weight: bold;
	color: #F00;
	font-size: 14pt;
}
.govde {
	font-family: Calibri;
	font-style: italic;
	font-size: 12pt;
}
.linki {
	font-family: Calibri;
	font-size: 12px;
	color: #306;
}
.liste {
	font-family: Calibri;
	text-align: center;
	font-size: 12px;
	font-weight: bold;
	color: #000;
}
-->
</style>
</head>

<body>

<table width="100%" border="0">
<%
		
		TumVeri = fonkXmlHttp("http://www.google.com.tr/search?hl=tr&q=fontarsivi.gen.tr") 'veriyi buraya postlayacaksın
		Tum_Cikan_Sonuclar = fonkVeriCek(TumVeri, _
                                         "<h2 class=hd>Arama Sonuçları</h2><div><ol>", _
                                         "</div><br clear=""all""/>")

        Do
            CikanSonuclar_SatirSatir = fonkVeriCek(Tum_Cikan_Sonuclar, _
                                                   "<li class=g>", "</span></div>")
            CikanSonuclar_Link = fonkVeriCek(CikanSonuclar_SatirSatir, _
                                             "<a href=""", """ ")
            CikanSonuclar_Baslik = fonkVeriCek(CikanSonuclar_SatirSatir, ")"">", _
                                               "</a>")
            CikanSonuclar_Icerik = fonkVeriCek(CikanSonuclar_SatirSatir, _
                                               "<div class=""s"">", "<b>")

            If (Len(CikanSonuclar_Link) > 3) Then
			i=i+1
			%>
           
             <tr <%If (i mod 2)=1 then%>bgcolor="#FFCC00"<%End If%>>
             	<td width="4%" class="liste"><%=i%></td>
   					<td width="96%">
             			<table width="100%" border="0">
                    		<tr>
        						<td class="baslik"><%=CikanSonuclar_Baslik%></td>
      						</tr>
      						<tr>
        						<td class="govde"><%=CikanSonuclar_Icerik %></td>
     						</tr>
      						<tr>
        						<td class="linki"><%=CikanSonuclar_Link %></td>
      						</tr>
    					</table>
            	</td>
  			</tr>
            <%
			End If

            Tum_Cikan_Sonuclar = Replace(Tum_Cikan_Sonuclar, _
                                         "<li class=g>" & CikanSonuclar_SatirSatir _
                                         & "</span></div>", "")

        Loop While Not (Len(CikanSonuclar_Link) < 3)
      
%>
</table>
</body>
</html>

kendine göre geliştirir ve düzenlersin kolay gelsin iyi çalışmalar.