Resim silme

Arkadaşlar ilan sitem üzerinde bir ilanı sildiğim zaman ( id nosuna göre siliyor ) ilana ait resimleride silmesini istiyorum

access veri tabanı kullanıyorum
yardımcı olursanız sevinirim. Teşekkürederim

Veri yolu ......
<%

if(Request.Querystring("id") <> "") then Adsdelete__varId = Request.Querystring("id")

%>

<%

set Adsdelete = Server.CreateObject("ADODB.Command")
ilansil.ActiveConnection = MM_connilanlar_STRING
ilansil.CommandText = "DELETE FROM ILANLAR WHERE AD_ID = " + Replace(ilansil__varId, "'", "''") + ""
ilansil.CommandType = 1
ilansil.CommandTimeout = 0
ilansil.Prepared = true
ilansil.Execute()
response.redirect "ilanpanel.asp"
%>

resimler farklı bir tabloyamı ekleniyor? tam olarak açıklarmısın eğer ki farklı tabloya ekleniyorsa o tablonun ismi ve sütunlarını yazmalısın..

resimi sanırım normal klasöre yükletiyorsundur.
FSO ile çok basitçe 2-3 satır kodla silme işlemini yapabilirsin.

Evet aynı tablo içinde (ILANLAR) IMAGE1, IMAGE2 ve IMAGE3 adında 3 sütuna ayrı ayrı yazıyor , yani ilanla ilgili bütün bilgiler tek bir tablo içinde yeralıyor silme işlemini id nosuna göre yaptırıyorum, ilan resimleri de RESİMLER klasörü içine upload ediliyor.

<%
strDosyaAdi = "images/resimadi.jpg"

Set DosyaSilme = Server.CreateObject("Scripting.FileSystemObject")
DosyaSilme.DeleteFile (Server.MapPath(strDosyaAdi))

%>

FSO ile dosya silme kodu böyle, artık kendinize göre uyarlarsınız

Arkadaşlar benim yapamadığım şey ilana ait resimlerin otomatik silinmesini. Şuan yaptığım şey SİL dediğim zaman ilana ait bütün bilgileri siliyor, aynı kodlara FSO yöntemini uyarlamaya çalıştım ama beceremedim. Çalışır durumdaki Kodları aşağıya yazayım Kullanmak isteyen arkadaşlarada faydası olur. Bu kodlara FSO yu nasıl ekleyebileceğim konusunda yardımlarınızı halaa beklemekteyim, buarada her ilana ait 3 resim bulunuyor ve resim isimleride aynı tablede farklı sütunlarda yazıyor... teşekkür ederim.
SİLME LİNKİ:

<a href="ilansil.asp?id=<%=(rsAds.Fields.Item("AD_ID").Value)%>">SİL</a>

SİLME İŞLEMİ YAPAN DOSYA : (ilansil.asp)

<!--#include file="baglanti.asp" -->
<%
if(Request.Querystring("id") <> "") then Adsdelete__varId = Request.Querystring("id")
%>
<%
set Adsdelete = Server.CreateObject("ADODB.Command")
Adsdelete.ActiveConnection = MM_connilan_STRING
Adsdelete.CommandText = "DELETE FROM ILANLAR WHERE AD_ID = " + Replace(Adsdelete__varId, "'", "''") + ""
Adsdelete.CommandType = 1
Adsdelete.CommandTimeout = 0
Adsdelete.Prepared = true
Adsdelete.Execute()
response.redirect "ilanlarim.asp"
%>

EDİT : Arkadaşlar dosya ismini yazarak silmeyi biliyorum benim yapamadığım yukardaki SİL linkini tıkladığım zaman resimlerinde silinmesini sağlamak.

Aşağıda istediğin işlemi yapabileceğin kod var.
Umarım işini görür.

Kolay gelsin.

 
<%
 
 ' Resimlerin bulunduğu klasör (Fiziksel path ile örnek verdim. Mappath ile de kullanabilirsin)
 strResimKlasor = "D:\Inetpub\wwwroot\resimler\"
 
  ' ID parametresini iID değişkenie yükledik
  iID = Request.QueryString("ID")
 
   ' Eğer numeric bir veri yoksa dedik
   if Not IsNumeric(iID) Then
    Response.Write"Lütfen silmek istediğiniz kaydı belirtiniz."
   else
 
    'Veritabanındaki ilgili tabloya bağlanıp o kaydın olup olmadığını kontrol edicez
    Set objRs = Server.CreateObject("ADODB.RecordSet")
    strSQL = "SELECt * FROM ILANLAR WHERE AD_ID = "& iID
    objRs.Open strSQL, objConn,1 ,3 
     if objRs.EOF Then
      Response.Write"Silmek istediğiniz kayıt bulunamadı"
     else
 
      ' fso nesneyini saklandığı yerden çıkarıyoruz
      Set fso = CreateObject("Scripting.FileSystemObject")
 
      ' Eğer IMAGE1 alanında veri varsa
      if Not IsNULL(objRs("IMAGE1")) Then
       ' Eğer IMAGE1 alanındaki veri fiziksel olarak hostta bulunuyorsa
       if fso.FileExists(strResimKlasor & objRs("IMAGE1")) Then  
        ' Bulunuyorsa silinecek dosyayı alıyoruz
        Set f1 = fso.GetFile(strResimKlasor & objRs("IMAGE1"))
        ' Siliyoruz
        f1.Delete
       end if
      end if
 
      ' Yukarıdaki işlemler burada da yapılıyor
      if Not IsNULL(objRs("IMAGE2")) Then      
       if fso.FileExists(strResimKlasor & objRs("IMAGE2")) Then                  Set f2 = fso.GetFile(strResimKlasor & objRs("IMAGE2"))
        f2.Delete
       end if      
      end if
      if Not IsNULL(objRs("IMAGE3")) Then      
       if fso.FileExists(strResimKlasor & objRs("IMAGE3")) Then       
        Set f3 = fso.GetFile(strResimKlasor & objRs("IMAGE3"))
        f3.Delete
       end if      
      end if
      ' İLgili kaydı siliyoruz
      strSQL1 = "DELETE * FROM ILANLAR WHERE AD_ID = "& iID
      objConn.Execute(strSQL1) 
 
      'Gidilecek yere gönderiyoruz
      Response.Redirect "ilanlarim.asp"         
 
      'Bittiiiii
     end if
    objRs.Close
    Set objRs = Nothing
   end if
%>