Klasik Asp ile 2 resmi yan yana birleştirme

Klasik asp ile 2 resmi yan yana birleştirmenin yolu var mı arkadaşlar. Üst üste değil. Yan yana.

Hocam ASP tek başına bu şekilde işlemi yanılmıyorsam yapamıyor.
Fakat ASP Persits Jpeg Bileşeni istediğiniz işlemin yapılabileceğini düşünüyorum. Aşağıda ki bağlantıda konuya yakın bir döküman bulunmakta. Teknik açıdan yardımcı olabilir

http://www.aspjpeg.com/manual_06.html

sanki daha öncedende böyle bişey sormuştunuz, toplam resim boyutu vs sabitse örnek atın bakayım. persist ile yapılması lazım

Evet daha önce sormuştum çözüm bulamadım. Resim boyutu sabit değil . 4000x 4000 px.Boyutunda bazen 10 bazen 20 resmi yanyana birleştirmem gerekiyor panoramik şekilde

default.asp

<FORM ENCTYPE="multipart/form-data" ACTION="upload.asp" METHOD="POST">
<INPUT TYPE="FILE" NAME="FILE1" multiple >
<br>
<INPUT TYPE="SUBMIT" VALUE="Upload!">
</FORM>

upload.asp

<%

Set Upload = Server.CreateObject("Persits.Upload")

Count = Upload.Save

If Count = 0 Then
Response.Write "No images selected."
Response.End
Else
genisliktoplam=0
yukseklikmax=0
For Each File in Upload.Files
If File.ImageType <> "UNKNOWN" Then
Set jpeg = Server.CreateObject("Persits.Jpeg")
jpeg.OpenBinary( File.Binary )
genislik=Jpeg.OriginalWidth
yukseklik=Jpeg.OriginalHeight
genisliktoplam=genislik+genisliktoplam
if yukseklikmax < yukseklik then yukseklikmax=yukseklik
End If
next

response.write " toplam genislik:" & genisliktoplam & "<br>"
response.write "maksimum yukseklik:" & yukseklikmax& "<br>"

'tüm resimler okundu tabanlik yapım resimleri üzerine basalım

Set Jpeg2 = Server.CreateObject("Persits.Jpeg")
Jpeg2.New genisliktoplam , yukseklikmax, &HFFFFFF
ykonum=0
For Each File2 in Upload.Files
If File2.ImageType <> "UNKNOWN" Then
Set jpegtemp = Server.CreateObject("Persits.Jpeg")
jpegtemp.OpenBinary( File2.Binary )
response.write ykonum
Jpeg2.Canvas.DrawImage ykonum, 0, jpegtemp' optional arguments omitted
ykonum=ykonum+jpegtemp.OriginalWidth 'resimleri yan yana getirmek için genişliği kadar öteleme yapmak için
End if
NEXT

Jpeg2.Save (Server.MapPath("sadas.jpg"))

End If



%>

çalışması için, aspjpeg ve aspupload bileşenlerinin yüklü olması gerekmektedir.

Teşekkür ederim. yalnız kodlar hata veriyor. form sayfası upload ediyor sonra hata. persits yüklü sunucuda. birde ben upload ederek değilde sunucumda örneğin resim klasörü içindeki 1.jpg, 2.jpg, 3.jpg gibi resimleri okuyarak birleştirmek istiyorum

dosya yazma izinleri vermelisiniz o yüzden hata veriyordur. hocam kodları kendi yapmak istediğinize göre düzenlersiniz, jpeg.open ile istediğiniz bir path deki dosya(lar)ı açabilirsiniz gerisi aynı olur zaten.

hocam teşekkür ederim. yardımınız sayesinde istediğim şekilde çalışır hale getirdim. son olarak persits aspjpeg bileşenini lisans sorunu olmadan nasıl kurabilirim serial vs bulamadım nette. aslında bir tane kurdum serial girerek ama lisanslı oldu mu olmadı mı anlamadım

hocam forumda serial istemek filan yasak o yüzden o konuda bir şey diyemem ama
Set Jpeg = Server.CreateObject("Persits.Jpeg")
den sonda
Jpeg.key
yazarak, elinizde herhangibi bir satı alınmış key varsa kullanabilirsiniz. demo çalışıp çalışmadığını test etmek içi bilgisayarın tarihini ileri alabilirsiniz. zaten key expriretted,purshe it gibi bir hata veriyor