Flash & ActionScript 2.0 Uygulamalı Dersler

Kademeli Önyükleyici (Preloader)

%25'e geldiğinde şu, %50'e geldiğinde şu olsun diyeceğiniz bir çalışma düşünüyorsanız, Aşağıda ki hazırladığım örneği kullanabilirsiniz.

hepsi = _root.getBytesTotal();
yuklenen = _root.getBytesLoaded();
yuzde = Math.round(yuklenen/hepsi*100);
if (yuzde>0 and yuzde<25) {
	trace("birinci klip");
	// %25e kadar olmasını istediğin olayları buraya
} else if (yuzde>25 and yuzde<50) {
	trace("ikinci klip");
	// %50ye kadar olmasını istediğin olayları buraya
} else if (yuzde>50 and yuzde<75) {
	trace("üçüncü klip");
	// %75e kadar olmasını istediğin olayları buraya
} else if (yuzde>75 and yuzde<100) {
	trace("son klip");
	// en son olmasını istediğin olayları buraya ekle.
}
if (hepsi == yuklenen) {
	gotoAndPlay(2);
}

teşekkürler, konu sabitlenirse güzel olur

Rica ederim;

Konu sabitlenip, katılımlarda bulunulur ve güzel bir kaynak oluşturulabilirse Flash ile yeni tanışan, sorularına cevap bulamayan, hatalarına çözüm arayanlar için hoş olur.
Fırsat buldukça bir çok yeni çalışma ve anlatım sunacağım.

Kolay gelsin.

evet konu sabitlenmeli. +rep

Youtube'de kullanılan tarz'da bir buton/menü çalışması.

* Yeni bir çalışma penceresi açtıktan sonra boyutlar farketmez istediğiniz şekilde sayfa boyutlandırmasında bulunabilirsiniz.

Sahnemize 4 ayrı buton çizelim farklı renklerde olmak üzere, her birini ayrı ayrı movieclip haline getirdikten sonra instance name'lerine sırası ile buton1, buton2, buton3 ve buton4 isimlerini verelim.

Tüm bunları tamamladıktan sonra layerimizin ilk frame'ine aşağıda ki kodları girelim.

var butonlar:Array = [buton1, buton2, buton3, buton4];

function efekt(id:Number, secilen:Boolean) {
	if (secilen == true) {
		for (i=0; i<butonlar.length; i++) {
			if (id == i) {
				alphaTo(butonlar[i],100);
				yTo(butonlar[i],butonlar[i].ilky+5);
			} else {
				alphaTo(butonlar[i],50);
				yTo(butonlar[i],butonlar[i].ilky);
			}
		}
	} else {
		for (i=0; i<butonlar.length; i++) {
			yTo(butonlar[i],butonlar[i].ilky);
			alphaTo(butonlar[i],100);
		}
	}
}
function uygula() {
	for (i=0; i<butonlar.length; i++) {
		butonlar[i]._alpha = 100;
		butonlar[i].ilkx = butonlar[i]._x;
		butonlar[i].ilky = butonlar[i]._y;
		butonlar[i].id = i;
		butonlar[i].onRollOver = function() {
			efekt(this.id,true);
		};
		butonlar[i].onRollOut = function() {
			efekt(this.id,false);
		};
	}
}
function alphaTo(movclip:MovieClip,deger:Number) {
	if(movclip.alphaTo_movclip == undefined) {
		movclip.createEmptyMovieClip("alphaTo_movclip",1);
	}
	movclip.a = deger;
	movclip.alphaTo_movclip.onEnterFrame = function() {
		this._parent._alpha+=(this._parent.a-this._parent._alpha)*0.3;
	}
}
function yTo(movclip:MovieClip,deger:Number) {
	if(movclip.yTo_movclip == undefined) {
		movclip.createEmptyMovieClip("yTo_movclip",2);
	}
	movclip.y = deger;
	movclip.yTo_movclip.onEnterFrame = function() {
		this._parent._y+=(this._parent.y-this._parent._y)*0.3;
	}
}
uygula();

Kodu frame'e yerleştirdikten sonra CTRL+Enter ile test edebilirsiniz, üzerine geldiğinizde seçili olan buton alpha(görünürlük) düşüp aşağı doğru hareket edecektir.

Bu sadece rollOver(üzerine gelindiğinde) olması gerekenleri temsil eder ben tıkladığımda da şu şu şu özellikler olsun derseniz bunun için de size kolaylık sağlaması açısından şu şekilde anlatayım.

Tıklanıldığında faaliyet göstertmesini istediğiniz butonu seçin ve Action Panelini açın (F9) açtıktan sonra.

on (release) {
// burada olmasını istediğiniz özellikleri yazabilirsiniz, örneğin tıklanıldığında R10'u açtıralım.
getURL ("https://www.r10.net","_blank");
}

Tüm butonlar için bunu kullanabilirsiniz, butonları çoğaltabilirsiniz yalnız çoğalttığınız her buton için verecek olduğunuz instance name'i ilk frame'de bulunan "butonlar =" bölümüne eklemeyi unutmayınız.

Ön izleme;

Download;

Kar Yağdırtma Efekti

Daha öncelerden verilmiş olan çalışma deaktif olduğundan yeni bir çalışma hazırlamak istedim;

Yeni bir çalışma sahnesi açtıktan sonra, sahnemize öncelikle bir kar taneciği çizmemiz gerekmektedir.

3x3 pixel bir daire çizelim ve bunu movieclip haline getirelim, movieclip haline getirdiğimiz dairemize Filter uygulaması ile beyaz glow efekti verelim. Bu arada unutmadan movieclip ismine "kar" diyiniz ki karıştırmayalım.

Tüm bunları yaptıktan sonra dairemizi sahnemizden silelim "Dikkat: Silecek olduğumuz clip sadece Library(Kütüphane)'de kalmalı kütüphaneden değil sadece sahnemizden sileceğiz.

Şimdi dairemizi sildikten sonra kütüphanemize gelelim ve movieclip ismini "kar" olarak belirlediğimiz Clip'imize sağ tıklayalım orada görecek olduğunuz Linkage tuşuna basalım.

Bir panel açılacak ve panel'de Export for ActionScript isimli check'i aktif edelim Identifier bölümüne de kar dedikten sonra Ok tuşuna basalım.

Tüm bunları yaptıktan sonra, birinci frame'imize gelelim ve şu kodları girelim.

karyagdirma = function () {
	width = 800;
	height = 600;
	kar_boyutu = 20;
	kar_taneleri = 60;
	for (i=0; i<kar_taneleri; i++) {
		t = attachMovie("kar", "kar"+i, i);
		t._alpha = 20+Math.random()*60;
		t._x = -(width/2)+Math.random()*(1.5*width);
		t._y = -(height/2)+Math.random()*(1.5*height);
		t._xscale = t._yscale=50+Math.random()*(kar_boyutu*10);
		t.k = 1+Math.random()*2;
		t.kivrim = -1.5+Math.random()*(1.4*3);
		t.onEnterFrame = uygulama;
	}
};
uygulama = function() {
	this._y += this.k;
	this._x += this.kivrim;
	if (this._y>height+10) {
		this._y = -20;
	}
	if (this._x>width+20) {
		this._x = -(width/2)+Math.random()*(1.5*width);
		this._y = -20;
	} else if (this._x<-20) {
		this._x = -(width/2)+Math.random()*(1.5*width);
		this._y = -20;
	}
}
karyagdirma();

Tüm bunları doğru yaptığınızdan eminseniz, CTRL+Enter ile test edebilirsiniz.
Kar efektimizde size kolaylık sağlaması açısından "büyüklük ve küçüklük", "kar tane sayısını", "başlangıç ve bitiş noktalarını" kendinize göre ayarlamanız için dinamik tuttum kod içerisinden istediğiniz gibi değiştirebilirsiniz.

Önizleme

Download

Elinize sağlık. Bu action script global fonksiyonların tam olarak ne işe yaradıkları ile ilğili Türkçe bir kaynak bulmamız mümkünmü. Flash daki action script panelinde view help yaptıgımda bana ingilizce olarak örnekler veriyor. Böle Türkçe bir kaynak varmı. Mesala rollOver maus üstüne gelince bunu biliyorum. Ama bilmediğim bir sürü fonksiyon var. Bu konu hakkında bana yardımcı olurmusunuz.

Eline sağlık,rep'liyecektim lakin yerinde yok

Benim bildiğim online Türkçe bir metin kaynağı mevcut değil, sadece kitaplarda mevcuttur.
Savaş TEKİN kitaplarına göz atarsan şayet sana yardımcı olacak en güzel faktördür.